src/BuildSystem/BuildFile.pm

# BuildFile
#
# Interface
# ---------
# new(toolbox)
# ParseBuildFile($base,$path,$file)
# ParseBuildFileExport(filename)
# BlockClassPath() : Return the class path
# ignore()      : return 1 if directory should be ignored 0 otherwise
# CheckBuildFile(dir) : return the BuildFile if it exists

package BuildSystem::BuildFile;
use ActiveDoc::SimpleDoc;
use BuildSystem::ToolBox;
require 5.004;

BEGIN {
$buildfile="BuildFile";
}

sub new {
        my $class=shift;
        my $self={};
        bless $self, $class;
        $self->{toolbox}=shift;
        $self->{Arch}=1;
        push @{$self->{ARCHBLOCK}}, $self->{Arch};
        return $self;
}

sub ignore {
        my $self=shift;
        return (defined $self->{ignore})?$self->{ignore}:0;
}

sub _initswitcher {
        my $self=shift;
        my $switch=ActiveDoc::SimpleDoc->new();
        my $parse="makebuild";
        $switch->newparse($parse);
        $switch->addignoretags($parse);
        $self->_commontags($switch,$parse);
        $switch->addtag($parse,"Build", \&Build_start, $self);
        $switch->addtag($parse,"none",
                                        \&OutToMakefile,$self,
                                        \&OutToMakefile, $self,
                                        "", $self);
        $switch->addtag($parse,"Bin",
                                        \&Bin_start,$self,
                                        \&OutToScreen, $self,
                                        "", $self);
        $switch->addtag($parse,"LibType",
                                        \&LibType_Start,$self,
                                        \&LibType_text, $self,
                                        \&LibType_end,$self);
        $switch->addtag($parse,"ConfigurationClass",
                                        \&Class_StartTag,$self,
                                        \&OutToMakefile, $self,
                                        "", $self);
        $switch->addtag($parse,"ClassPath",
                                        \&setBlockClassPath,$self,
                                        \&OutToMakefile, $self,
                                        "", $self);
        $switch->addtag($parse,"AssociateGroup",
                                        "",$self,
                                        \&AssociateGroup,$self,
                                        "", $self);
        $switch->addtag($parse,"Environment",
                                        \&Environment_start,$self,
                                        \&OutToMakefile, $self,
                                        \&Environment_end,$self);
        $switch->addtag($parse,"Export",
                                        \&export_start,$self,
                                        \&OutToMakefile, $self,
                                        \&export_end,$self);
        return $switch;
}

sub _commontags {
        my $self=shift;
        my $switch=shift;
        my $parse=shift;

        $switch->grouptag("Export",$parse);
        $switch->addtag($parse,"Use",\&Use_start,$self,
                                               \&OutToMakefile, $self,
                                                "", $self);
        $switch->addtag($parse,"Group",\&Group_start,$self,
                                               \&OutToMakefile, $self,
                                                "", $self);
        $switch->grouptag("Group",$parse);
        $switch->addtag($parse,"External",
                                        \&External_StartTag,$self,
                                        \&OutToMakefile, $self,
                                        "", $self);
        $switch->addtag($parse,"lib",
                                        \&lib_start,$self,
                                        \&OutToMakefile, $self,
                                        "", $self);
        $switch->addtag($parse,"Architecture",
                                        \&Arch_Start,$self,
                                        \&OutToMakefile, $self,
                                        \&Arch_End,$self);
        $switch->addtag($parse,"INCLUDE_PATH",
                                        \&IncludePath_Start,$self,
                                        \&OutToMakefile, $self,
                                        "",$self);
        return $switch;
}

sub GenerateMakefile {
        my $self=shift;
        my $infile=shift;
        my $outfile=shift;

        $self->{switch}=$self->_initswitcher();
        $self->{switch}->filetoparse($infile);

        # open a temporary gnumakefile to store output.
        my $fh=FileHandle->new();
        open ( $fh, ">$outfile") or die "Unable to open $outfile for output ".
                                                                "$!\n";
        @{$self->{filehandlestack}}=($fh);

        #  -- make an alias
        *GNUmakefile=$fh;
        if ( -e $ENV{LatestBuildFile} ) {
          print GNUmakefile "include $ENV{LatestBuildFile}\n";
        }
        $ENV{LatestBuildFile}=$outfile;
        $self->{switch}->parse("makebuild"); # sort out supported tags
        close GNUmakefile;
}

sub ParseBuildFile {
        my $self=shift;
        my $base=shift;
        my $path=shift;
        my $filename=shift @_;
        my $fullfilename;
        if ( $filename!~/^\// ) {
         $fullfilename="$base/$path/$filename";
        }
        else {
         $fullfilename=$filename;
        }
        $self->{path}=$path;
        #print "Processing $fullfilename\n";
        $numbins=0;
        $self->{envnum}=0;
        $self->{envlevel}=0;
        $self->{currentenv}="$ENV{LOCALTOP}/$ENV{INTwork}/$self->{path}/".
                                                                "BuildFile.mk";
        $ENV{SCRAM_CURRENTENV}=$self->{currentenv};

        #open a temporary gnumakefile to store output.
        use Utilities::AddDir;
        AddDir::adddir("$ENV{LOCALTOP}/$ENV{INTwork}/$self->{path}");
        $self->GenerateMakefile($fullfilename,
          $ENV{LOCALTOP}."/".$ENV{INTwork}."/".$self->{path}."/BuildFile.mk");
}

sub ParseBuildFile_Export {
        my $self=shift;
        my $filename=shift;
        my $bf=BuildSystem::BuildFile->new($self->{toolbox});
        if ( defined $self->{remoteproject} ) {
           $bf->{remoteproject}=$self->{remoteproject};
        }
        $bf->_parseexport($filename);
        undef $bf;
}

sub _location {
        my $self=shift;
        use File::Basename;

        return dirname($self->{switch}->filetoparse());
}

sub _parseexport {
        my $self=shift;
        my $filename=shift;

        my $switchex=ActiveDoc::SimpleDoc->new();
        $switchex->filetoparse($filename);
        $switchex->newparse("export");
        $switchex->addignoretags("export");
        $switchex->addtag("export","Export",
                                        \&export_start_export,$self,
                                        \&OutToMakefile, $self,
                                        \&export_end_export,$self);
        $self->_commontags($switchex,"export");
        $switchex->allowgroup("__export","export");
#       $switchex->{Strict_no_cr}='no';
        $self->{switch}=$switchex;
        $switchex->parse("export"); # sort out supported tags
}

sub _pushremoteproject {
        my $self=shift;
        my $path=shift;
        
        if ( defined $self->{remoteproject} ) {
          push @{$self->{rpstack}}, $self->{remoteproject};
        }
        $self->{remoteproject}=$path;
}

sub _popremoteproject {
        my $self=shift;
        if ( $#{$self->{rpstack}} >=0 ) {
          $self->{remoteproject}=pop @{$self->{rpstack}};
        }
        else {
          undef $self->{remoteproject};
        }
}

sub _toolmapper {
        my $self=shift;
        if ( ! defined $self->{mapper} ) {
           require BuildSystem::ToolMapper;
           $self->{mapper}=BuildSystem::ToolMapper->new();
        }
        if ( @_  ) { #if a class is supplied then supply the map directly
           my $class=shift;
           return $self->{mapper}->getmap($class);  
        }
        return $self->{mapper};
}


# ---- Tag routines 

# -- Override a class type with the <ConfigurationClass type=xxx> tag
#    the type tag will pick up a pre-defined class type from project space.

sub Class_StartTag {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;
        
        if ( $self->{Arch} ) {
         if ( defined $$hashref{'type'} ) {
                $ClassName=$$hashref{'type'};
         }
        }
}
 
sub IncludePath_Start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->checktag( $name, $hashref, 'path');
        if ( $self->{Arch} ) {
          print GNUmakefile "INCLUDE+=".$self->_location()."/".
                                                $$hashref{'path'}."\n";
        }
}

#
# generic build tag
#
sub Build_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->checktag($name,$hashref,'class');
        $self->{switch}->checktag($name,$hashref,'src');
        if ( $self->{Arch} ) {

          # -- determine the build products name
          my $name;
          if ( exists $$hashref{'name'} ) {
            $name=$$hashref{'name'};
          }
          else { 
            $self->{switch}->parseerror("No name specified for build product");
            #$name="\$(buildname)";
          }

          # -- check we have a lookup for the class type
          my $mapper=$self->_toolmapper($$hashref{'class'});
          if ( ! defined $mapper ) {
            $self->{switch}->parseerror("Unknown class : ".$$hashref{'class'});
          }
          else {
           my @types=$mapper->types();

           # -- get default build rules
           my @deftypes;
           if ( ! exists $$hashref{'default'} ) {
             @deftypes=$mapper->defaulttypes();
           }
           else {
             @deftypes=split /,/, $$hashref{'default'};
           }

           my $fh=$self->{filehandlestack}[0];
           my @targets=();

           # -- generate generic targets
           print $fh "ifndef _BuildLink_\n";
           print $fh "# -- Generic targets\n";
           push @targets, $$hashref{'class'};
           push @targets, $$hashref{'class'}."_".$$hashref{'name'};
           foreach $dtype ( @deftypes ) {
            print $fh $$hashref{'class'}."::".$$hashref{'class'}."_".
                                                                $dtype."\n";
            print $fh $$hashref{'class'}."_".$$hashref{'name'}.
                        "::".$$hashref{'class'}."_".$dtype."_".
                        $$hashref{'name'}."\n";
           }
           print $fh "\n";

           # -- generate targets for each type
           foreach $type ( @types ) {

            # -- generic name for each type
            my $pattern=$$hashref{'class'}."_".$type;
            my $dirname=$$hashref{'class'}."_".$type."_".$name;
            print $fh "# ------ $pattern rules ---------------\n";
            print $fh $$hashref{'class'}."_".$type."::".$$hashref{'class'}.
                                                        "_".$type."_$name\n\n";

            # -- create a new directory rule for each type
            push @targets, $pattern;
            my $here="$ENV{LOCALTOP}/$ENV{INTwork}/\$(THISDIR)/".$dirname;
            my $work=$ENV{INTwork}."/\$(THISDIR)/".$dirname;
            my $makefile=$here."/BuildFile.mk";

            # -- create link targets to the directory
            push @targets, $dirname;
            print $fh "# -- Link Targets to $type directories\n";
            print $fh "$dirname: make_$dirname\n";
            print $fh "\t\@cd $here; \\\n";
            print $fh "\t\$(MAKE) LatestBuildFile=$makefile _BuildLink_=1".
                        " workdir=$work ".
                        " -f \$(TOOL_HOME)/basics.mk datestamp \$\@; \n\n";

            # -- write target to make makefile for each directory
            print $fh "# -- Build target directories\n";
            print $fh "make_$dirname:\n";
            print $fh "\t\@if [ ! -f \"$makefile\" ]; then \\\n";
            print $fh "\t if [ ! -d \"$here\" ]; then \\\n";
            print $fh "\t  mkdir $here; \\\n";
            print $fh "\t fi;\\\n";
            #print $fh "\t echo include ".$self->{currentenv}." > ".
            print $fh "\t echo include \$(SCRAM_CURRENTENV) > ".
                                                        "$makefile; \\\n";
            print $fh "\t echo VPATH+=$ENV{LOCALTOP}/".${THISPATH}.
                                        " >> $makefile; \\\n";
            print $fh "\t echo buildsrcfiles:=".$$hashref{'src'}.
                                " >> $makefile; \\\n";
            print $fh "\t echo buildname=$name >> $makefile;\\\n";
            print $fh "\t echo ".$dirname.":".$pattern." >> $makefile;\\\n";
            print $fh "\t echo ifdef DefaultBuildFile >> $makefile; \\\n";
            print $fh "\t echo include \$(DefaultBuildFile) >> $makefile; \\\n";
            print $fh "\t echo DefaultBuildFileIn=true >> $makefile; \\\n";
            print $fh "\t echo endif >> $makefile; \\\n";
            if ( defined (my @file=$mapper->rulesfile($$hashref{'class'})) ) {
             foreach $f ( @file ) {
              print $fh "\t echo -include $f >> $makefile; \\\n";
             }
            }
            print $fh "\tfi\n";
            print $fh "\n";
#           print $typefile "$name :\n";
#           print $typefile "\t\$(_quietbuild_)";
#           print $typefile $mapper->template($$hashref{'class'},$type)."\n";
#           print $typefile "\t\$(_quietstamp_)";
#           print $typefile "$(SCRAM_HOME)/src/scramdatestamp \$@.ds \$@ \$^\n";

            # -- debug targets
            print $fh "# -- debug targets\n";
            print $fh $dirname."_echo_% : make_$dirname\n";
            print $fh "\t\@cd $here; \n";
            print $fh "\t\@\$(MAKE) LatestBuildFile=$makefile _BuildLink_=1".
                        " workdir=$work ".
                        " -f \$(TOOL_HOME)/basics.mk ".
                        "echo_\$(subst ".$dirname."_echo_,,\$\@) ; \n\n";
            push @targets, $dirname."_echo_VAR";

            # -- cleaning targets
            push @targets, "clean_$dirname";
            print $fh "# -- cleaning targets\n";
            print $fh "clean::clean_$dirname\n";
            print $fh "clean_".$dirname."::\n";
            print $fh "\t\@if [ -d $here ]; then \\\n";
            print $fh "\techo cleaning $dirname; \\\n";
            print $fh "\tcd $here; \\\n";
            print $fh "\t\$(MAKE) LatestBuildFile=$makefile workdir=".
                        $work." _BuildLink_=1 -f ".
                        "\$(TOOL_HOME)/basics.mk clean; \\\n";
            print $fh "\tfi\n\n";


          }
          # -- help targets
          print $fh "helpheader::\n";
          print $fh "\t\@echo Targets available:\n";
          print $fh "\t\@echo ------------------\n\n";
          print $fh "help::helpheader\n";
          foreach $target ( @targets ) {
            print $fh "help::\n";
            print $fh "\t\@echo $target\n"
          }
          print $fh "endif\n";
         } # end else
        }
}

sub Bin_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        my $fileclass;
        my @tools;
        my $tool;
        my $filename;
        my $objectname;
        
        $self->{switch}->checktag($name,$hashref,'file');
        if ( $self->{Arch} ) {
          if ( ! defined $$hashref{name} ) {
                ($$hashref{name}=$$hashref{file})=~s/\..*//;
          }
          ($filename=$$hashref{file})=~s/^\///; # make sure full paths dont work
           $self->Build_start($name,{ "class" => "bin",
                                   "src" => $filename,
                                   "name"  => $$hashref{'name'} } );
        }
}

sub External_StartTag {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;
        
        my $tool;
        if ( $self->{Arch} ) {
        $self->{switch}->checktag($name,$hashref,'ref');

        # -- oo toolbox stuff
        # - get the appropriate tool object
        $$hashref{'ref'}=~tr[A-Z][a-z];
        if ( ! exists $$hashref{'version'} ) {
         $tool=$self->{toolbox}->gettool($$hashref{'ref'});
        }
        else {
         $tool=$self->{toolbox}->gettool($$hashref{'ref'},$$hashref{'version'});
        }
        if ( ! defined $tool ) {
          $self->{switch}->parseerror("Unknown Tool Specified ("
                                                        .$$hashref{'ref'}.")");
        }

        # -- old fashioned GNUmakefile stuff
        print GNUmakefile $$hashref{'ref'};
        if ( defined $$hashref{'version'} ) {
                print GNUmakefile "_V_".$$hashref{'version'};
        }
        print GNUmakefile "=true\n";
        
        # -- Sub system also specified?
        if ( exists $$hashref{'use'} ) {
           # -- look for a buildfile
           my @paths=$tool->getfeature("INCLUDE");
           my $file="";
           my ($path,$testfile);
           foreach $path ( @paths ) {
             $testfile=$path."/".$$hashref{'use'}."/BuildFile" ;
             if ( -f $testfile ) { 
                $file=$testfile; 
                $self->_pushremoteproject($path);
             }
           }
           if ( $file eq "" ) {
             $self->{switch}->parseerror("Unable to find SubSystem $testfile");
           }
           $self->ParseBuildFile_Export($file);
           $self->_popremoteproject();
         }
        }
}       

sub Group_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;
        
        $self->{switch}->checktag($name, $hashref, 'name');
        if ( $self->{Arch} ) {
        print GNUmakefile "GROUP_".$$hashref{'name'};
        if ( defined $$hashref{'version'} ) {
                print GNUmakefile "_V_".$$hashref{'version'};
        }
        print GNUmakefile "=true\n";
        }
}       

sub Use_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;
        my $filename;
        use Utilities::SCRAMUtils;
        
        $self->{switch}->checktag($name, $hashref, "name");
        if ( $self->{Arch} ) {
        if ( exists $$hashref{'group'} ) {
          print GNUmakefile "GROUP_".$$hashref{'group'}."=true\n";
        }
        if ( ! defined $self->{remoteproject} ) {
          $filename=SCRAMUtils::checkfile(
                "/$ENV{INTsrc}/$$hashref{name}/BuildFile");
        }
        else {
          $filename=$self->{remoteproject}."/$$hashref{name}/BuildFile";
        print "trying $filename\n";
          if ( ! -f $filename ) { $filename=""; };
        }
        if ( $filename ne "" ) {
          $self->ParseBuildFile_Export( $filename );
        }
        else {
           $self->{switch}->parseerror("Unable to detect Appropriate ".
                "decription file for <$name name=".$$hashref{name}.">");
        }
        }
}

sub CheckBuildFile {
         my $self=shift;
         my $classdir=shift;
         my $ClassName="";
         my $thisfile="$classdir/$buildfile";
 
         if ( -e $ENV{LOCALTOP}."/".$thisfile ) {
            $DefaultBuildfile="$ENV{LOCALTOP}/$thisfile";
            $self->ParseBuildFile($ENV{LOCALTOP}, $classdir, $buildfile);
         }
         elsif ( -e $ENV{RELEASETOP}."/".$thisfile ) {
            $DefaultBuildfile="$ENV{RELEASETOP}/$thisfile";
            $self->ParseBuildFile($ENV{RELEASETOP}, $classdir, $buildfile);
         }
         return $ClassName;
}

# List association groups between <AssociateGroup> tags
# seperated by newlines or spaces
sub AssociateGroup {
        my $self=shift;
        my $name=shift;
        my $string=shift;
        my $word;

        foreach $word ( (split /\s/, $string) ){
                chomp $word;
                next if /^#/;
                if ( $word=~/none/ ) { 
                        $self->{ignore}=1;
                }
        }
}

sub Arch_Start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->checktag($name, $hashref,'name');
        ( ($ENV{SCRAM_ARCH}=~/$$hashref{name}.*/) )? ($self->{Arch}=1) 
                                                : ($self->{Arch}=0);
        push @{$self->{ARCHBLOCK}}, $self->{Arch};
}

sub Arch_End {
        my $self=shift;
        my $name=shift;

        pop @{$self->{ARCHBLOCK}};
        $self->{Arch}=$self->{ARCHBLOCK}[$#{$self->{ARCHBLOCK}}];
}

# Split up the Class Block String into a useable array
sub _CutBlock {
    my $self=shift;
    my $string= shift @_;
    @BlockClassA = split /\//, $string;
}

sub OutToMakefile {
        my $self=shift;
        my $name=shift;
        my @vars=@_;

        if ( $self->{Arch} ) {
          print GNUmakefile @vars;
        }
}

sub OutToScreen {
        my $name=shift;
        my @vars=@_;

        if ( $self->{Arch} ) {
          print @vars;
        }
}
sub setBlockClassPath {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->checktag($name, $hashref, 'path');
        $self->{BlockClassPath}=$self->{BlockClassPath}.":".$$hashref{path};
        $self->_CutBlock($$hashref{path});
}

sub BlockClassPath {
        my $self=shift;
        return $self->{BlockClassPath};
}

sub export_start_export {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->opengroup("__export");
}

sub export_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->opengroup("__export");
        if ( exists $$hashref{autoexport} ) {
          print GNUmakefile "scram_autoexport=".$$hashref{autoexport}."\n";
          if ( $$hashref{autoexport}=~/true/ ) {
           $self->{switch}->allowgroup("__export","makebuild");
          }
          else {
           $self->{switch}->disallowgroup("__export","makebuild");
          }
        }
        # -- allow default setting from other makefiles
        print GNUmakefile "ifeq (\$(scram_autoexport),true)\n";
}

sub export_end_export {
        my $self=shift;
        $self->{switch}->closegroup("__export");
}

sub export_end {
        my $self=shift;
        $self->{switch}->closegroup("__export");
        print GNUmakefile "endif\n";
}

#
# Standard lib tag 
#
sub lib_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        $self->{switch}->checktag($name, $hashref, 'name');
        if ( $self->{Arch} ) {
           print GNUmakefile "lib+=$$hashref{name}\n";
        }
}

#
# libtype specification
#
sub LibType_Start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        if ( $self->{Arch} ) {
        if ( defined $self->{libtype_conext} ) {
          $self->{switch}->parseerror("<$name> tag cannot be specified".
                " without a </$name> tag to close previous context");
        }
        else {
        $self->{libtype_conext}=1;
        $self->{switch}->checktag($name, $hashref, 'type');
        
        print GNUmakefile "# Specify Library Type\n";
        print GNUmakefile "DefaultLibsOff=yes\n";
        if ( $$hashref{'type'}=~/^archive/i ) {
          print GNUmakefile "LibArchive=true\n";
        }
        elsif ($$hashref{'type'}=~/debug_archive/i ) {
          print GNUmakefile "LibDebugArchive=true\n";
        }
        elsif ($$hashref{'type'}=~/debug_shared/i ) {
          print GNUmakefile "LibDebugShared=true\n";
        }
        elsif ($$hashref{'type'}=~/shared/i ) {
          print GNUmakefile 'LibShared=true'."\n";
        }
        print GNUmakefile "\n";
        }
        }
}

sub LibType_text {
        my $self=shift;
        my $name=shift;
        my $string=shift;

        if ( $self->{Arch} ) {
          $string=~s/\n/ /g;
          print GNUmakefile "libmsg::\n\t\@echo Library info: ";
          print GNUmakefile $string;
          print GNUmakefile "\n";
        }
}

sub LibType_end {
        my $self=shift;
        my $name=shift;

        undef $self->{libtype_conext};
}

sub Environment_start {
        my $self=shift;
        my $name=shift;
        my $hashref=shift;

        if ( $self->{Arch} ) {
          $self->{envnum}++;

          # open a new Environment File
          my $envfile="$ENV{LOCALTOP}/$ENV{INTwork}/$self->{path}/Env_".
                $self->{envnum}.".mk";
          use FileHandle;
          my $fh=FileHandle->new();
          open ($fh,">$envfile") or die "Unable to open file $envfile \n$!\n";
          push @{$self->{filehandlestack}}, $fh;
          *GNUmakefile=$fh;

          # include the approprate environment file
          if ( $self->{envlevel} == 0 ) {
             print GNUmakefile "include $ENV{LOCALTOP}/$ENV{INTwork}/".
                $self->{path}."/BuildFile.mk\n";
          }
          else {
             print GNUmakefile "include $ENV{LOCALTOP}/$ENV{INTwork}/".
                $self->{path}."/Env_".$self->{Envlevels}[$self->{envlevel}].".mk\n";
          }
          $self->{envlevel}++;
          $self->{Envlevels}[$self->{envlevel}]=$self->{envnum};
          $self->{currentenv}="$ENV{LOCALTOP}/$ENV{INTwork}/$self->{path}/Env_$self->{envnum}.mk";
        }
        $ENV{SCRAM_CURRENTENV}=$self->{currentenv};
}

sub Environment_end {
        my $self=shift;
        my $fd;

        if ( $self->{Arch} ) {
          $self->{envlevel}--;
          if ( $self->{envlevel} < 0 ) {
            print "Too many </Environent> Tags on $self->{switch}->line()\n";
            exit 1;
          }
          close GNUmakefile;
          # restore the last filehandle
          $fd=pop @{$self->{filehandlestack}};
          close $fd;
          *GNUmakefile=$self->{filehandlestack}[$#{$self->{filehandlestack}}];
          if ( $self->{envlevel} < 1 ) {
            $self->{currentenv}="$ENV{LOCALTOP}/$ENV{INTwork}/$self->{path}/".
                        "BuildFile.mk";
          }
          else {
            $self->{currentenv}=
             "$ENV{LOCALTOP}/$ENV{INTwork}/$self->{path}/Env_".
                $self->{Envlevels}[$self->{envlevel}];
          }
          $ENV{SCRAM_CURRENTENV}=$self->{currentenv};
        }
}
Revision:	1.1.2.20
Committed:	Wed Jun 14 19:28:00 2000 UTC (24 years, 11 months ago) by williamc
Content type:	text/plain
Branch:	V0_9branch
Changes since 1.1.2.19:	+4 -3 lines
Log Message:	fix cleaning targets