[ViewVC] Annotation of: cvsroot/COMP/SCRAM/src/scram

#!/usr/local/bin/perl5 
# ^^^^^^^^^^^^^^^^^^^^
# we dont need this anymore to invoke perl but options placed here will be
# used.
#
# User Interface
#
# Make sure were running the right version

versioncheck();

# -- handle options
while ( $ARGV[0]=~/^-/) {
        if ( $ARGV[0] eq "-verbose" ) {
          shift @ARGV;
          print "verbose mode for $ARGV[0] on\n";
          scrambasics()->classverbose($ARGV[0],1);
        }
        elsif ( $ARGV[0] eq "-arch" ) {
          shift @ARGV;
          $ENV{SCRAM_ARCH}=$ARGV[0];
          scrambasics()->arch($ARGV[0]);
        }
        else {
          error("Unknown option $ARGV[0]");
        }
        shift @ARGV;
}

$inputcmd=shift;
$found='false';
$bold  = "\033[1m";
$rv=0;
$normal = "\033[0m";
$self={};

@allowed_commands=qw(project build install version list arch setup runtime db tool url);
@dev_cmds=qw(devtest devint align);


if ( $inputcmd ne "" ) {
 foreach $command ( (@allowed_commands,@dev_cmds) ) {
         if ( $command=~/^$inputcmd/i) { 
                # Deal with a help request
                do{     helpheader($command);
                        &{"help_".$command}; exit; } if $ARGV[0]=~/help/i;
                $rv=&$command; $found='true'; 
                last;
         }
 }
}

if ( ! ( $found=~/true/ ) ) {
        helpheader('Recognised Commands');
        foreach $command ( @allowed_commands ) {
        print "      $bold scram ".$command.$normal."\n";       
        }
        print "\n";
        print "Help on individual commands available through\n\n";
        print "$bold       scram".$normal." command$bold help $normal\n\n";

        print "\nOptions:\n";
        print "--------\n";
        print $bold."-verbose ".$normal."Class    : Activate the verbose".
                    "function on the specified class";
        print "\n\n";
        print $bold."-arch ".$normal."architecture : Set the architecture id".
                    "to that specified";
        print "\n\n";
}
exit $rv;

sub error {
        my $string=shift;
        print "scram : ".$string."\n";
        exit 1;
}

sub versioncheck {
        my $version;

        if ( @_ ) {
           $version=shift;
        }
        else {
         # -- get version from local area
         if ( ! localtop_find() ) {
         LoadEnvFile();
         my $versionfile=$ENV{LOCALTOP}."/$ENV{projconfigdir}/scram_version";
          if ( -f $versionfile ) {
           open (VERSION, "<".$versionfile);
            $version=<VERSION>;
            chomp $version;
          }
         }
        }
        if ( defined $version ) {
          scrambasics()->spawnversion($version,@ARGV);
        }
}

#
#
# _procescmds(handlercoderef,refarrayofallowedcommands,
#               refarrayofactualcommands,arrayofsubroutinestringstocall)
#
#
sub _processcmds {
        my $optionhandler=shift;
        my $allowed_commands=shift;
        my $cmds=shift;
        my @subs=@_;

        my $found=0;
        # make a string from the subcommand levels
        my $substring="";
        if ( @subs ) {
           $substring= join '_', @subs;
           $substring=$substring."_";
        }

        # Process options
        if ( defined ${$cmds}[0] ) {
        while ( ${$cmds}[0]=~/^-/) {
           &{$optionhandler}( ${$cmds}[0],$cmds);
        }

        my $inputcmd=shift @{$cmds};
        if ( $inputcmd ne "" ) {
         foreach $command ( @{$allowed_commands} ) {
           if ( $command=~/^$inputcmd/i) {
                # Deal with a help request
                if ( ( defined $$cmds[0]) && $$cmds[0]=~/help/i ) {
                   &helpheader($command,@subs);
                   &{"help_".$substring.$command}; exit;
                }
                else {
        #print "calling $substring".$command."(@{$cmds})\n";
                   &{$substring.$command}(@{$cmds}); $found=1;
                   last;
                }
           }
         }
        }
        }
        if ( ! $found ) {
          &{$substring."error"}(@subs);
        }
        return $found;
}


sub help_build {
        &build;
}

sub align {
        _localarea()->align();
}

sub build {
        # is this a based or free release?
        FullEnvInit();
        $ENV{MAKETARGETS}=join ' ',@ARGV;

        # -- set the runtime environment
        my $toolrt=scrambasics()->toolruntime(_localarea());
        $toolrt->sethash(\%Env);

        # -- set up the builder
        #require BuildSystem::BuildSetup;
        #my $bs=BuildSystem::BuildSetup->new(toolbox());
        #$rv=$bs->BuildSetup($ENV{THISDIR},@ARGV);
        #$rv;
        require BuildSystem::Build;
        my $bs=BuildSystem::Build->new(_localarea());
        $rv=$bs->build($ENV{THISDIR},@ARGV);
        return $rv->status();
}

sub project {
        my @args=@ARGV;

        my $devareaname="";
        use Cwd;
        my $installarea=cwd();

        # process options
        while ( $args[0]=~"^-" ) {
         if ( $args[0]=~/-n/ ) {
           shift @args;
           $devareaname=shift @args;
         }
         elsif ( $args[0]=~/-d/ ) {  #installation area directory 
          shift @args;
          $installarea=$args[0];
          if ( ! -d $installarea ) {
                error("$installarea does not exist");
          }
          shift @args;
         }
         else {
          error("unknown option $args[0] to project command");
         }
        } 

        # -- check what arguments have been passed
        if ( $#args <0 || $#args>1 ) {
          error("\"scram project help\" for usage info");
        }
        my $area; #somewhere to store the area object when we have it

        if ( ( $#args==0 ) && ($args[0]=~/:/) ) { 
          # -- must be a url to bootstrap from
          $area=scrambasics()->project($args[0], $installarea,
                                                $devareaname);
          scrambasics()->setuptoolsinarea($area);
        }
        elsif ( $#args >0 ) { 
          # -- get the release area
          my $relarea=scrambasics()->scramprojectdb()->getarea(@args);
          if ( ! defined $relarea ) {
             error("Unknown project @args");
          }
          # -- we need to spawn the correct scram version to handle it
          unshift @ARGV, "project";
          versioncheck($relarea->scramversion());
          
          # -- need to create a satellite area
          $area=scrambasics()->satellite(@args,$installarea, $devareaname);
        }
        else {
          error("\"scram project help\" for usage info");
        }
        
        #
        # Now create the directories specified in the interface
        # There should be some better mechanism - TODO
        #
        chdir $area->location();
        foreach $key ( keys %ENV ) {
         if ( $key=~/^INT/ ) {
                AddDir::adddir($ENV{$key});
         }
        }

        print "\nInstallation Procedure Complete. \n".
                "Installation Located at:\n".$area->location()."\n";
}

sub scrambasics {
        require Scram::ScramFunctions;
        if ( ! defined $scramobj ) {
           environmentinit();
           $scramobj=Scram::ScramFunctions->new();
           $scramobj->arch($ENV{SCRAM_ARCH});
           #$scramobj->verbosity(1);
        }
        return $scramobj;
}

# ------------ url command --------------------------------------------
sub url {
        @_=@ARGV;
        localtop();
        environmentinit();
        my @allowed_cmds=qw(get);
        _processcmds("_tooloptions", \@allowed_cmds, \@_, ("url"));
}

sub url_get {
        my $url=shift;
        my $area=_localarea();

        ($uurl,$file)=scrambasics()->webget($area,$url);
        print "$file\n";
}

sub help_url {
print <<ENDTEXT;
URL information.

SubCommands :
        scram url get

ENDTEXT
}

sub help_url_get {
print <<ENDTEXT;
Description:
        Return the location of the local copy of the specified url
Usage :
        scram url get url

ENDTEXT
}

# ------------ tool command --------------------------------------------
sub tool {
        @_=@ARGV;
        localtop();
        environmentinit();
        my @allowed_cmds=qw(info list default setup);
        _processcmds("_tooloptions", \@allowed_cmds, \@_, ("tool"));    
}

sub tool_error {
        error("Unknown tool subcommand : @_");
}

sub tool_default {
        if ( $#_ != 1 ) {
          error("\"scram tool default help\" for usage information");
        }
        my $tool=shift; 
        my $version=shift;
        print "Setting default version of $tool to $version\n";
        # -- adjust the toolbox
        toolbox()->setdefault($tool,$version);

}

sub tool_list {
        my $area=_localarea();
        print "Tool List for "; #.$area->name()." ".$area->version()."\n";
        print "Location : ".$area->location()."\n";
        print "+"x60;
        print "\n";
        foreach $t ( toolbox()->tools() ) {
          my $vers=join / /, toolbox()->versions($t);
          print $t." ".$vers." (default=".toolbox()->defaultversion($t).")\n";
        }
}

sub tool_info {
        my $project=shift;
        my $area=_localarea();
        print "Tool Info as configured in "; 
                        #.$area->name()." ".$area->version()."\n";
        print "Location : ".$area->location()."\n";
        print "+"x60;
        print "\n";

        my @tools=toolbox()->gettool($project,@_);
        foreach $t ( @tools ) {
          if ( defined $t ) {
           print "Name : ".$t->name();
           print "\n";
           print "Version : ".$t->version();
           print "\n";
           print "Docfile : ".$t->url();
           print "\n";
           print "+"x20;
           print "\n";
           @features=$t->features();
           foreach $ft ( @features ) {
             @vals=$t->getfeature($ft);
             foreach $v ( @vals ) {
               print $ft. "=$v\n";
             }
           }
          }
        }
}

sub tool_setup {
        print "Please use scram setup command\n";
}

sub _tooloptions {
        error("No Options defined for tool subcommand");
}

sub help_tool {
print <<ENDTEXT;
Manage the tools in the scram area that define the areas environment.
tool subcommands :
        list
        info tool_name
        default tool_name tool_version

ENDTEXT
}

sub help_tool_info {
print <<ENDTEXT;
Description:
        Print out information on the specified tool in the current area
        configuration.
Usage :
        scram tool info tool_name [tool_version]

ENDTEXT
}

sub help_tool_list {
print <<ENDTEXT;
Description:
        List of currently configured tools available in ther current scram
        area
Usage :
        scram tool list

ENDTEXT
}

sub help_tool_default {
print <<ENDTEXT;
Description:
        Change the default version of a tool to be used in the area
Usage :
        scram tool default tool_name tool_version

ENDTEXT
}

# ----------------------------------------------------------------------
sub _requirements {
        if ( ! defined $reqsobj ) {
          localtop();
          my $area=_localarea();
          scrambasics()->arearequirements($area)
        }
        return $reqsobj;
}

sub _allprojectinitsearcher {
        my $search=_projsearcher();
        foreach $proj ( _scramprojdb()->list() ) {
           $search->addproject($$proj[0],$$proj[1]);
        }
}

sub _projsearcher {
        if ( ! defined $self->{projsearcher} ) {
          require Scram::ProjectSearcher;
          $self->{projsearcher}=Scram::ProjectSearcher->new(_scramprojdb());
        }
        return $self->{projsearcher};
}

sub _scramprojdb {
        return scrambasics()->scramprojectdb(); 
}

sub runtime {
        my $shell;
        require Runtime;

        # process options
        while ( $ARGV[0]=~"^-" ) {
         if ( $ARGV[0]=~/-sh/ ) {
           shift @ARGV;
           $shell="sh";
           next;
         }
         if ( $ARGV[0]=~/-csh/ ) {  #installation area directory 
          shift @ARGV;
          $shell="csh";
          next;
         }
         print "Unknown Option $ARGV[0]\n";
         exit 1;
        } 

        FullEnvInit();
        if ( @ARGV ) {
           my $runtime=Runtime->new();
           my $arg=shift @ARGV;

           my $info=0;
           if ( $arg eq "info" ) {
              $arg=shift @ARGV;
              $info=1;
           }

           # --- determine filename
           my $filename;
           if ( -f $arg ) { # Is it a file?
              $filename=$arg;
           }
           else {
               # -- lets see if its a BuildFile location
               $filename=_testfile($ENV{LOCALTOP}."/src/".$arg,
                                $ENV{RELEASETOP}."/src/".$arg,
                                $ENV{LOCALTOP}."/src/".$arg."/BuildFile",
                                $ENV{RELEASETOP}."/src/".$arg."/BuildFile");
               if ( $filename eq "" ) {
                   print "Unable to find a file (or BuildFile) relating to ".
                        $arg."\n";
                   exit 1;
               }
           }
           $runtime->file($filename);
           if ( ! $info ) {
             $runtime->printenv($shell);
           }
           else {
             if ( @ARGV ) { #do we have a specific variable request?
                  _printvardoc($runtime,shift @ARGV);
             }
             else {
                foreach $var ( $runtime->list() ) {
                  _printvardoc($runtime,$var);
                } 
             }
           }
           undef $runtime;
        }
        else {
        FullEnvInit();
        # -- We have to clean up from the last runtime cmd - use env history
        foreach $variable ( %ENV ) {
          if ( $variable=~/^SCRAMRT_(.*)/ ) { #SCRAMRT are history retaining
            my $var=$1;
            $ENV{$var}=~s/\Q$ENV{$variable}\E//g;
            $ENV{$var}=~s/^:*//;  # Deal with any Path variables
            #print "$variable : $ENV{$variable} \n$var : $ENV{$var}\n";
            delete $ENV{$variable};
          }
        }

        # -- get the tool runtime environments
        my $toolrt=scrambasics()->toolruntime(_localarea());
        $toolrt->sethash(\%EnvRuntime);

        # -- create new SCRAMRT history vars.
        foreach $variable ( keys %EnvRuntime ) {
          printoutenv($shell,"SCRAMRT_$variable",$EnvRuntime{$variable});
          #addvar("SCRAMRT_$variable", $EnvRuntime{$variable}, "");
        }
        
        # TODO -- this stuff should dissappear with compiler description docs
        # Now adapt as necessary - include base environment as well
        if ( exists $ENV{LD_LIBRARY_PATH} ) {
           addpath("LD_LIBRARY_PATH","$ENV{LD_LIBRARY_PATH}");
        }
        if ( exists $ENV{MANPATH} ) {
           addpath("MANPATH","$ENV{MANPATH}");
        }
        addpath("PATH","$ENV{PATH}");

        # -- Print out as reqd
        # TODO -- we can use the runtime class method once we have removed
        # this stuff above
        foreach $variable ( keys %EnvRuntime ) {
          printoutenv($shell,$variable,$EnvRuntime{$variable});
        }
        }
}

# Support rt for runtime

sub _testfile {
        my @files=@_;

        my $filename="";
        foreach $file ( @files ) {
          if ( -f $file ) {
                $filename=$file;
                last;
          }
        }
        return $filename;
}

sub _printvardoc {
        my $runtime=shift;
        my $var=shift;

        print $var." :\n";
        print $runtime->doc($var);
        print "\n";
}

sub printoutenv {
        my $shell=shift;
        my $variable=shift;
        my $value=shift;

        if ( $shell eq "csh" ) {
          print "setenv $variable \"$value\";\n";
        }
        elsif ( $shell eq "sh" ) {
          print "$variable=\"$value\";\n";
          print "export $variable;\n";
        }
}

sub addpath {
        my $name=shift;
        my $val=shift;

        my $n;
        my @env;
        @env=split /:/, $EnvRuntime{$name};
        foreach $n ( (split /:/, $val ) ){
         if (  ! grep /^\Q$n\E$/, @env ) {
          addvar($name,$n,":");
         }
        }
}

sub addvar {
        my $name=shift;
        my $val=shift;
        my $sep=shift;

        if ( $val ne "" ) {
        if ( defined $EnvRuntime{$name} ) {
         $EnvRuntime{$name}=$EnvRuntime{$name}.$sep.$val;
        }
        else {  
         $EnvRuntime{$name}=$val;
        }
        }
}

sub FullEnvInit {
    environmentinit();
    localtop();
    LoadEnvFile();
}

sub environmentinit {
        use Utilities::setarchitecture;
        my $name;
        my $value;

        $ENV{LatestBuildFile}=""; # stop recursive behaviour in make
        if ( ! defined $ENV{SCRAM_ARCH} ) {
          setarchitecture::setarch();
        }
        $ENV{INTwork}="tmp/$ENV{SCRAM_ARCH}";
        $ENV{INTsrc}="src";
        $ENV{INTlog}="logs";
        $ENV{INTlib}="lib/".$ENV{SCRAM_ARCH};

        ($ENV{SCRAM_BASEDIR}=$ENV{SCRAM_HOME})=~s/(.*)\/.*/$1/;
        if ( ! ( exists $ENV{SCRAM_CONFIG} ) ){
                $ENV{SCRAM_CONFIG}="$ENV{SCRAM_HOME}/configuration";
        }
        $ENV{TOOL_HOME}="$ENV{SCRAM_HOME}/src";
        if ( ! ( exists $ENV{SCRAM_LOOKUPDB} ) ){
                if ( -d "$ENV{SCRAM_BASEDIR}/scramdb/" ) {
                  $ENV{SCRAM_LOOKUPDB}="$ENV{SCRAM_BASEDIR}/scramdb/project.lookup";
                }
                else {
                  $ENV{SCRAM_LOOKUPDB}="$ENV{SCRAM_CONFIG}/project.lookup";
                }
        }
        $ENV{SCRAM_AVAILDIRS}="";
        $ENV{SCRAM_AVAILFILES}="";
}

sub _localarea {
        if ( ! defined $self->{localarea} ) {
          require Configuration::ConfigArea;
          $self->{localarea}=Configuration::ConfigArea->new();
          if ( ! defined $ENV{LOCALTOP} ) {
           if ( $self->{localarea}->bootstrapfromlocation() ) {
            # Were not in a local area 
            undef $self->{localarea};
           }
           else {
             $self->{localarea}->archname(scrambasics()->arch());
           }
          }
          else {
            $self->{localarea}->bootstrapfromlocation($ENV{LOCALTOP});
          }
        }
        return $self->{localarea};
}

sub localtop_find {
        my $rv=1;
        if ( defined _localarea()) {
          $rv=0;
          $ENV{LOCALTOP}=_localarea()->location();
        }
        return $rv;
}

sub localtop {
        localtop_find();
        if ( ! (defined $ENV{LOCALTOP}) ) {
         print "Unable to locate the top of local release. Exiting\n";
         exit 1;
        }
        ($ENV{THISDIR}=cwd)=~s/^\Q$ENV{LOCALTOP}\L//;
        $ENV{THISDIR}=~s/^\///;
}

sub LoadEnvFile {
        _localarea()->copyenv(\%ENV);
}

sub env {
   print "Sorry - Not yet\n";
}

sub devint {
        my $class=shift @ARGV;
        scrambasics()->scramobjectinterface($class);
}

sub devtest {
        require Utilities::TestClass;
        my $class=shift @ARGV;

        my $tester;
        my $path;

        #_initproject();
        if ( $class=~/::/ ) {
           ($path=$class)=~s/(.*)::.*/$1/;
        }
        $tester=Utilities::TestClass->new($class,
                "$ENV{SCRAM_HOME}/src/$path/test/testdata");
        $tester->dotest(@_);
}

#
# Create a lookup tag in the site database
#
sub install {
        localtop();
        scrambasics()->addareatoDB(_localarea(),@ARGV);
        _localarea()->align();
}

sub help_install()  {

print <<ENDTEXT;
Associates a label with the current release in the SCRAM database.
This allows other users to refer to a centrally installed project by
this label rather than a remote url reference.

Usage:

        $bold   scram install $normal [project_tag [version_tag]]

porject_tag : override default label (the project name of the current release)
version_tag : the version tag of the current release. If version is not
          specified the base release version will be taken by default.

ENDTEXT
}

sub helpheader ($label) {
        my $label=shift;
print <<ENDTEXT;
*************************************************************************
                   SCRAM HELP --------- $label 
*************************************************************************
ENDTEXT
}

sub version {
        my $version=shift @ARGV;
        my $thisversion;
        my $scram_top;
        my $cvsobject;

        ($thisversion=$ENV{SCRAM_HOME})=~s/(.*)\///;
        $scram_top=$1;
        if ( $version eq "" ) {
          print "$thisversion";
          # deal with links
          $version=readlink $ENV{SCRAM_HOME};
          if ( defined $version)  {
                print " ---> $version";
          }
          print "\n";
        }
        else {
          if ( -d $scram_top."/".$version ) {
                print "Version $version exists\n";
          }
          else {
              print "Version $version not available locally\n";
              print "Attempting download from the SCRAM repository\n";
              # set up and configure the cvs module for SCRAM
              require Utilities::CVSmodule;
              $cvsobject=Utilities::CVSmodule->new();
              $cvsobject->set_base(
                "cmscvs.cern.ch:/cvs_server/repositories/SCRAM");
              $cvsobject->set_auth("pserver");
              $cvsobject->set_user("anonymous");
              $cvsobject->set_passkey("AA_:yZZ3e");
              # Now check it out in the right place
              chdir $scram_top or die "Unable to change to $scram_top $!\n";
              $cvsobject->invokecvs( ( split / /, 
                        "co -d $version -r $version SCRAM" ));
                
              # Get rid of cvs object now weve finished
              $cvsobject=undef;
              print "\n";
          }
        }
        0;
}

sub list {
        &environmentinit;
        if ( ! -f $ENV{SCRAM_LOOKUPDB} ) {
          print "No installation database available - perhaps no projects".
                " have been installed locally\n";
          exit 1;
        }
        print "Installed Projects\n";
        print "------------------\n";
        print "|Project Name  | Project Version |\n";
        print "----------------------------------\n";
        listDB(@ARGV);
}

sub db {
        my $subcmd=shift @ARGV;
        &environmentinit;

        switch : {
        if ( $subcmd eq 'link' ) {
          scrambasics()->scramprojectdb()->link(@ARGV);
          last switch;
        }
        if ( ! -f $ENV{SCRAM_LOOKUPDB} ) {
          print "No installation database available - perhaps no projects".
                "have been installed locally\n";
          exit 1;
        }
        if ( $subcmd eq 'unlink' ) {
          scrambasics()->scramprojectdb()->unlink(@ARGV);
          last switch;
        }
        if ( $subcmd eq 'showlinks' ) {
          my @links=scrambasics()->scramprojectdb()->listlinks();
          foreach $link ( @links ) {
            print $link."\n";
          }
          last switch;
        }
        } # end switch
        
}

sub listDB {
        my $project="";
        if ( @_ ) {
          $project=shift;
        }
        my @prs=scrambasics()->scramprojectdb()->listall();
        foreach $pr ( @prs ) {
          if ( $project  eq "" || $project eq $$pr[0] ) {
          printf "%1s",$$pr[0];
          printf "%25s\n",$$pr[1];
          my $url=scrambasics()->scramprojectdb()->
                                getarea($$pr[0],$$pr[1])->location();
          printf "--> %25s\n",$url;
          }
        }
        0;
}

sub arch {
        &environmentinit();
        print "$ENV{SCRAM_ARCH}\n";
}


#
# Setup a new tool
#

sub setup {
        my $interactive=0;

        # process options
        while ( $ARGV[0]=~"^-" ) {
         if ( $ARGV[0]=~/-i/ ) {
           shift @ARGV;
           $interactive=1;
         }
         else {
          error("scram: unknown option $ARGV[0] to project command");
         }
        }

        localtop();
        my $area=_localarea();
        my $toolname=shift @ARGV;
        my $insert=0;
        toolbox()->interactive($interactive);

        # If no toolname specified then its a full setup
        if ( $toolname eq "" ) {
           # -- add architecture specific directories
           use Utilities::AddDir;
           AddDir::adddir($area->location()."/lib/$ENV{SCRAM_ARCH}");
           AddDir::adddir($area->location()."/bin/$ENV{SCRAM_ARCH}");
        
           # -- check the releasetop area
           # if the releasetop has the files copy them
           my $releaseobj=_releasearea();
           if ( $releaseobj->copysetup($ENV{LOCALTOP}) ) {
              print "Doing Full Setup\n";
              scrambasics()->setuptoolsinarea($area);
           }
        }
        else {
            scrambasics()->setuptoolsinarea($area, $toolname,@ARGV);
        }
}

sub _releasearea {
        if ( !defined $self->{releasearea} ) {
           require Configuration::ConfigArea;
           $self->{releasearea}=Configuration::ConfigArea->new();
           $self->{releasearea}->bootstrapfromlocation($ENV{RELEASETOP});
        }
        return $self->{releasearea};
}

# get a toolbox object for the local area
sub toolbox {
        if ( ! defined $toolbox ) {
           localtop();
           my $area=_localarea();
           $toolbox=scrambasics()->areatoolbox($area);
        }
        return $toolbox;
}

sub help_db {
print <<ENDTEXT;
scram database administration command. 

Usage:

                 $bold scram db $normal subcommand

subcommands:
        link : 
                Make available an additional database for 
                project and list operations

                $bold scram db link $normal /a/directory/path/project.lookup

        unlink : 
                Remove a database from the link list. Note this does
                not remove the database, just the link to it in scram.

                $bold scram db unlink $normal /a/directory/path/project.lookup

        showlinks : 
                List the databases that are linked in

ENDTEXT
}

sub help_setup {

print <<ENDTEXT;
Allows installation/re-installation of a new tool/external package into an 
already existing development area. If not toolname is specified, 
the complete installation process is initiated.

Usage:

                 $bold scram setup [-i]$normal [toolname] [[version] [url]]

toolname : The name of the tool setup file required.
version  : where more than one version exists specify the version
url      : when setting up a completely new tool specify the url too

The -i option turns off the automatic search mechanism allowing for more
user interaction with the setup mechanism
ENDTEXT
}

sub help_list {
print <<ENDTEXT;
List the available projects and versions installed in the local SCRAM database
(see scram install help) 

Usage:

        $bold   scram list $normal [ProjectName]

ENDTEXT
}

sub help_project {
print <<ENDTEXT;
Setup a new project development area. The new area will appear in the current 
working directory.
Usage:

        $bold scram project [-d install_area] [-n directory_name]$normal project_url [project_version]

Options:

project_url: The url of a scram bootstrap file.
             Currently supported types are:
                $bold Database label $normal
                        Labels can be assigned to bootstrap files for easy
                        access (See "scram install" command). If you
                        specify a label you must also specify a project_version.
                        e.g.

                           scram project SCRAM V1_0
                                
                           scram project ORCA ORCA_1_1_1

                        To see the list of installed projects use the
                        "scram list" command.

                $bold file: $normal A regular file on an accessable file system
                        e.g.

                           file:~/myprojects/projecta/config/BootStrapFile

project_version:
                 Only for use with a database label

-d install_area:
                 Indicate a project installation area into which the new
                 project area should appear. Default is the current working
                 directory.

-n directory_name:
                 Specify the name of the SCRAM development area you wish to 
                 create.
        
ENDTEXT
}

sub help_version {
print <<ENDTEXT;
With now $bold [version] $normal argument given, this command will simply
print to standard output the current version number.

Providing a version argument will cause that version to be downloaded and 
installed, if not already locally available. 


Usage:
                $bold scram version [version]$normal

ENDTEXT
}

sub help_arch {
print <<ENDTEXT;
Print out the architecture flag for the current machine.

Usage:
        $bold   scram arch $normal
ENDTEXT
}

sub help_runtime {
print <<ENDTEXT;
Echo to Standard Output the Runtime Environment for the current development area
Output available in csh or sh flavours

Usage:
        1) $bold   scram runtime [-csh|-sh] $normal
or
        2) $bold   scram runtime [-csh|-sh] filename $normal
or
        3) $bold   scram runtime info filename [variable]$normal

1) For the general configuration environment
2) For environment described in filename or 
                                areatop/src/directory/BuildFile 
3) Display information concerning the environment in the given file 
   (limited to variable if specified)

The file for cases 2) and 3) are searched as follows :
a) straightforward filename
b) filename relative to local_area/src
c) filename relative to release_area/src
d) BuildFile relative to local_area/src
e) BuildFile relative to release_area/src

Examples:

Setup the current environment to include the project Runtime Environment
in a csh environment

       $bold  eval `scram runtime -csh` $normal

Setup the current environment to include the project Runtime Environment in a
sh environment

       $bold  eval `scram runtime -sh` $normal


ENDTEXT
}
Revision:	1.35.2.2.2.9
Committed:	Thu Nov 2 17:38:46 2000 UTC (24 years, 6 months ago) by williamc
Branch:	V0_16branch
CVS Tags:	BuildSystemProto1, V0_18_0model, V0_18_0alpha
Changes since 1.35.2.2.2.8:	+8 -4 lines
Log Message:	update for new buildsystem